Hàm INDEX()

Hàm INDEX()

Một mục danh sách cụ thể

Trả về giá trị của một mục trong danh sách dựa trên giá trị chỉ mục của nó hoặc trả về giá trị trống nếu mục đó nằm ngoài danh sách.

Cú pháp

INDEX(listwhich-one)

  • list – Danh sách bất kỳ.
  • which-one – Chỉ số ( Number) của giá trị item cần lấy. Mục đầu tiên trong danh sách là 1.

Ví dụ:

INDEX(Students[Name], 1) trả về một giá trị tùy ý từ cột Name của bảng Students. Tùy ý vì thứ tự của các giá trị trong Students[Name]danh sách cột không được đảm bảo trừ khi được gọi thêm hàm SORT(). Tương đương với ANY(Students[Name])

INDEX(LIST("Red", "Yellow", "Green"), 2)trả về Text: Yellow

INDEX({"Red", "Yellow", "Green"}, 4) trả về “” (4 nằm ngoài danh sách).

Giá trị cao nhất trong cột

Giá sản phẩm cao nhất:

INDEX(SORT(SẢN PHẨM[Giá], TRUE), 1)

  1. SẢN PHẨM[Giá],lấy danh sách tất cả các giá trị từ cột Giá của bảng SẢN PHẨM
  2. SORT(..., TRUE)sắp xếp danh sách giá theo số lượng theo thứ tự giảm dần/cao xuống thấp ( TRUE).
  3. INDEX(..., 1)trả về giá đầu tiên trong danh sách được sắp xếp.

Tương đương với:MAX(SẢN PHẨM[Giá])

 

Số tháng theo tên

Tên tháng hôm nay (trả về Text):

INDEX(
  {
    "January", "February", "March",
    "April", "May", "June",
    "July", "August", "September",
    "October", "November", "December"
  },
  MONTH(TODAY())
)

  1. {"January", ...}xây dựng một danh sách các tên tháng.
  2. TODAY()trả về ngày hôm nay.
  3. MONTH(...)chuyển đổi một giá trị Date thành một số tương ứng với tháng trong năm.
  4. INDEX(..., MONTH(...))sử dụng số tháng để chọn tên tháng từ danh sách.

Tương đương với:

SWITCH(
  MONTH(TODAY()),
  1, "January",
  2, "February",
  3, "March",
  4, "April",
  5, "May",
  6, "June",
  7, "July",
  8, "August",
  9, "September",
  10, "October",
  11, "November",
  12, "December",
  ""
)

Số ngày trong tuần để đặt tên

Tên ngày trong tuần hôm nay (trả về Text):

INDEX(
  {
    "Sunday", "Monday", "Tuesday",
    "Wednesday", "Thursday", "Friday",
    "Saturday"
  },
  WEEKDAY(TODAY())
)

  1. {"Sunday", ...}xây dựng một danh sách tên các ngày trong tuần.
  2. TODAY()trả về ngày hôm nay.
  3. WEEKDAY(...)chuyển đổi một giá trị Date thành một số tương ứng với ngày trong tuần.
  4. INDEX(..., WEEKDAY(...))sử dụng số ngày trong tuần để chọn tên ngày trong tuần.

Tương đương với:

SWITCH(
  WEEKDAY(TODAY()),
  1, "Sunday",
  2, "Monday",
  3, "Tuesday",
  4, "Wednesday",
  5, "Thursday",
  6, "Friday",
  7, "Saturday",
  ""
)

Nếu có thắc mắc về bất kì thông tin nào cũng như cần hỗ trợ về ứng dụng hãy liên hệ với chúng tôi qua Hotline: 19002049. Chúng tôi luôn luôn sẵn lòng lắng nghe và hỗ trợ.

Nguồn: google

We will be happy to hear your thoughts

Leave a reply

Ecommerce Hub AppSheet VN
Logo
Reset Password
Compare items
  • Total (0)
Compare
0
Shopping cart